さかなになった

ばね運動とかフォースマップ、速度・加速度・抵抗とかのスタディでなんか作ってたらきもいかんじになってきて結構好きなのであげてみる。
もっと自由に動いたりしてほしいのだけど、角に止まっちゃったり、一定の動きをする場所にはまっちゃったりするので、フォースマップのやり方があまりうまくないとおもわれる。

Live demo.

水平なハズの横の線が斜めになって見えませんか？
カフェウォール錯視というものです。
じーっと見過ぎると酔いますｗ

・FDでテキストファイルを「ドキュメントを挿入」してもmimeTypeがつかない
・mimeType=”application/octet-stream”　を書き足す

package
{
	import flash.display.Sprite;
	import flash.events.Event;

	public class Main extends Sprite
	{
		[Embed(source='test.txt', mimeType="application/octet-stream")]
		private var Test_txt:Class; 

		public function Main():void
		{
			if (stage) init();
			else addEventListener(Event.ADDED_TO_STAGE, init);
		}

		private function init(e:Event = null):void
		{
			removeEventListener(Event.ADDED_TO_STAGE, init);
			// entry point

			var h:String = new Test_txt();
			trace(h);
		}

	}

}

今回のポイント
・SIgnalはターゲットという概念はない
・DeluxeSignalを使う
・DeluxeSignalのコンストラクタでターゲットを指定
・DeluxeSignal.dispatch(new GenericEvent())でイベント発火
・GenericEvent.targetで、DeluxeSignalのコンストラクタで指定したターゲットを受け取る

package
{
	import flash.display.Sprite;
	import flash.events.Event;
	import flash.events.MouseEvent;
	import org.osflash.signals.events.GenericEvent;
	import org.osflash.signals.Signal;

	/**
	 * ...
	 * @author ikekou : ikeda kousei
	 */
	public class Main7 extends Sprite
	{

		public function Main7():void
		{
			if (stage) init();
			else addEventListener(Event.ADDED_TO_STAGE, init);
		}

		private function init(e:Event = null):void
		{
			removeEventListener(Event.ADDED_TO_STAGE, init);
			// entry point

			var tama:Cat = new Cat();

			tama.sleeped.add(_onTamaSleeped);
			tama.sleep();
		}

		private function _onTamaSleeped(event:GenericEvent):void
		{
			trace("[ Main7 ] _onTamaSleeped");
			//event.targetで受け取る
			trace( "event.target : " + event.target );
		}

	}

}

import org.osflash.signals.DeluxeSignal;
import org.osflash.signals.events.GenericEvent;
import org.osflash.signals.Signal;

internal class Cat
{
	public var sleeped:DeluxeSignal;

	public function Cat()
	{
		//DeluxeSignalのコンストラクタでターゲットを指定
		sleeped = new DeluxeSignal(this);
	}

	public function sleep():void
	{
		//GenericEvent型わたす
		sleeped.dispatch(new GenericEvent());
	}
}

あと、NativeRelaySignalとNativeMappedSignalの使い方がまだ全然わからない。

今回のポイント
・Signal.add()で追加したイベントハンドラはSignal.remove()で外せる

package
{
	import flash.display.Sprite;
	import flash.events.Event;
	import flash.events.MouseEvent;
	import org.osflash.signals.Signal;

	/**
	 * ...
	 * @author ikekou : ikeda kousei
	 */
	public class Main6 extends Sprite
	{

		public function Main6():void
		{
			if (stage) init();
			else addEventListener(Event.ADDED_TO_STAGE, init);
		}

		private function init(e:Event = null):void
		{
			removeEventListener(Event.ADDED_TO_STAGE, init);
			// entry point

			var tama:Cat = new Cat();

			tama.jumped.add(_onTamaJumped);

			tama.jump();
			tama.jump();

			tama.jumped.remove(_onTamaJumped); //外す
			tama.jump(); //反応しない
		}

		private function _onTamaJumped():void
		{
			trace("[ Main6 ] _onTamaJumped");
		}

	}

}

import org.osflash.signals.Signal;

internal class Cat
{
	public var jumped:Signal;

	public function Cat()
	{
		jumped = new Signal();
	}

	public function jump():void
	{
		jumped.dispatch();
	}
}

1エントリ使うもんじゃなかった

今回のポイント
・Signal.addOnce()はadd()と同じだが、一度反応したら以降反応しない

package
{
	import flash.display.Sprite;
	import flash.events.Event;
	import flash.events.MouseEvent;
	import org.osflash.signals.Signal;

	/**
	 * ...
	 * @author ikekou : ikeda kousei
	 */
	public class Main4 extends Sprite
	{

		public function Main4():void
		{
			if (stage) init();
			else addEventListener(Event.ADDED_TO_STAGE, init);
		}

		private function init(e:Event = null):void
		{
			removeEventListener(Event.ADDED_TO_STAGE, init);
			// entry point

			var tama:Cat = new Cat();

			tama.jumped.add(_onTamaJumped);

			tama.jump();
			tama.jump();

			var momo:Cat = new Cat();

			momo.jumped.addOnce(_onMomoJumped);

			momo.jump();
			momo.jump(); //ここは反応しない
		}

		private function _onMomoJumped():void
		{
			trace("[ Main4 ] _onMomoJumped");
		}

		private function _onTamaJumped():void
		{
			trace("[ Main4 ] _onTamaJumped");
		}

	}

}

import org.osflash.signals.Signal;

internal class Cat
{
	public var jumped:Signal;

	public function Cat()
	{
		jumped = new Signal();
	}

	public function jump():void
	{
		jumped.dispatch();
	}
}

今回のポイント
・Signal.dispatch()は複数の値も渡せます。
・Signalのコンストラクタで指定する型もそれにあわせて複数指定できます。
・Arrayでも渡せます
・あわない型だとエラーが発生します。
・コンストラクタで指定する引数の数はあくまでも型チェック用なので、ここで指定しなくてもdispatch()では値は渡せます。
・コンストラクタの引数の数とSignal.dispatch()の引数の数があわない場合はあう分だけチェックがかかります。
・イベントハンドラ引数の数とSignal.dispatch()の引数の数があわないと当然エラーになります。デフォルト値を設定すれば大丈夫です。

package
{
	import flash.display.Sprite;
	import flash.events.Event;
	import org.osflash.signals.Signal;

	/**
	 * ...
	 * @author ikekou : ikeda kousei
	 */
	public class Main9 extends Sprite
	{

		public function Main9():void
		{
			if (stage) init();
			else addEventListener(Event.ADDED_TO_STAGE, init);
		}

		private function init(e:Event = null):void
		{
			removeEventListener(Event.ADDED_TO_STAGE, init);
			// entry point

			var tama:Cat = new Cat();
			addChild(tama);

			tama.jumped.add(_onTamaJumped);
			tama.jump();
		}

		private function _onTamaJumped(message1:String, message2:Number):void
		{
			trace("[ Main9 ] _onTamaJumped");
			trace( "message1 : " + message1 );
			trace( "message2 : " + message2 );
		}

	}

}

import flash.display.Sprite;
import org.osflash.signals.Signal;

internal class Cat extends Sprite
{
	public var jumped:Signal;

	public function Cat()
	{
		jumped = new Signal(); //渡す値の数と、ここでかける制限の数は関係ないからコンストラクタで指定なしでもOK
		//jumped = new Signal(String, Number); //dispatchで渡す値にあわせて型を指定
		//jumped = new Signal(String); //ひとつだけ指定すれば指定されている分だけチェックがかかる
		//jumped = new Signal([String, Number]); //引数が一つで、かつArrayなら、複数の引数を渡すかわりにこういうのもできる
	}

	public function jump():void
	{
		jumped.dispatch("jump!", 1);
	}
}

複数の値を渡すのは便利そう。
型の制限は複数人開発とか大規模開発とかに向いてそうだけど一人ではそこまで使わない気がする。

今回のポイント
・Signalクラスのコンストラクタの引数としてクラスを渡すと、前回やったSignal.dispatch()の引数として値を渡す際に型チェックがかかります。
・あわない型だとエラーが発生します。

package
{
	import flash.display.Sprite;
	import flash.events.Event;
	import flash.events.MouseEvent;
	import org.osflash.signals.Signal;

	/**
	 * ...
	 * @author ikekou : ikeda kousei
	 */
	public class Main3 extends Sprite
	{

		public function Main3():void
		{
			if (stage) init();
			else addEventListener(Event.ADDED_TO_STAGE, init);
		}

		private function init(e:Event = null):void
		{
			removeEventListener(Event.ADDED_TO_STAGE, init);
			// entry point

			var tama:Cat = new Cat();
			tama.jumped.add(_onTamaJumped);
			tama.jump();
			tama.sleeped.add(_onTamaSleeped);
			tama.sleep();

		}

		private function _onTamaJumped(message:String):void
		{
			trace("[ Main3 ] _onTamaJumped");
			trace(message);
		}

		private function _onTamaSleeped(message:Number):void
		{
			trace("[ Main3 ] _onTamaSleeped");
			trace(message);
		}

	}

}

import org.osflash.signals.Signal;

internal class Cat
{
	public var jumped:Signal;
	public var sleeped:Signal;

	public function Cat()
	{
		//Signalのコンストラクタに型を渡す
		jumped = new Signal(String);
		sleeped = new Signal(Number);
	}

	public function jump():void
	{
		jumped.dispatch("tama jump"); //String指定してるところにStringだからOK
	}

	public function sleep():void
	{
		//sleeped.dispatch("tama sleep"); //Numberを指定してるのにStringを渡すとErrorにしてくれる
		sleeped.dispatch(1); //こっちならNumberだしOK
	}
}

とはいってもまだこのチェックの使い道が思い浮かばない・・・うーん